374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
113 lines
3.5 KiB
Nix
113 lines
3.5 KiB
Nix
# This module defines a system-wide environment that will be
|
|
# initialised by pam_env (that is, not only in shells).
|
|
{
|
|
config,
|
|
lib,
|
|
options,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
|
|
cfg = config.environment;
|
|
|
|
in
|
|
|
|
{
|
|
|
|
options = {
|
|
|
|
environment.sessionVariables = lib.mkOption {
|
|
default = { };
|
|
description = ''
|
|
A set of environment variables used in the global environment.
|
|
These variables will be set by PAM early in the login process.
|
|
|
|
The value of each session variable can be either a string or a
|
|
list of strings. The latter is concatenated, interspersed with
|
|
colon characters.
|
|
|
|
Setting a variable to `null` does nothing. You can override a
|
|
variable set by another module to `null` to unset it.
|
|
|
|
Note, due to limitations in the PAM format values may not
|
|
contain the `"` character.
|
|
|
|
Also, these variables are merged into
|
|
[](#opt-environment.variables) and it is
|
|
therefore not possible to use PAM style variables such as
|
|
`@{HOME}`.
|
|
'';
|
|
inherit (options.environment.variables) type apply;
|
|
};
|
|
|
|
environment.profileRelativeSessionVariables = lib.mkOption {
|
|
type = lib.types.attrsOf (lib.types.listOf lib.types.str);
|
|
example = {
|
|
PATH = [ "/bin" ];
|
|
MANPATH = [
|
|
"/man"
|
|
"/share/man"
|
|
];
|
|
};
|
|
description = ''
|
|
Attribute set of environment variable used in the global
|
|
environment. These variables will be set by PAM early in the
|
|
login process.
|
|
|
|
Variable substitution is available as described in
|
|
{manpage}`pam_env.conf(5)`.
|
|
|
|
Each attribute maps to a list of relative paths. Each relative
|
|
path is appended to the each profile of
|
|
{option}`environment.profiles` to form the content of
|
|
the corresponding environment variable.
|
|
|
|
Also, these variables are merged into
|
|
[](#opt-environment.profileRelativeEnvVars) and it is
|
|
therefore not possible to use PAM style variables such as
|
|
`@{HOME}`.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = {
|
|
environment.etc."pam/environment".text =
|
|
let
|
|
suffixedVariables = lib.flip lib.mapAttrs cfg.profileRelativeSessionVariables (
|
|
envVar: suffixes:
|
|
lib.flip lib.concatMap cfg.profiles (profile: map (suffix: "${profile}${suffix}") suffixes)
|
|
);
|
|
|
|
# We're trying to use the same syntax for PAM variables and env variables.
|
|
# That means we need to map the env variables that people might use to their
|
|
# equivalent PAM variable.
|
|
replaceEnvVars = lib.replaceStrings [ "$HOME" "$USER" ] [ "@{HOME}" "@{PAM_USER}" ];
|
|
|
|
pamVariable =
|
|
n: v: ''${n} DEFAULT="${lib.concatStringsSep ":" (map replaceEnvVars (lib.toList v))}"'';
|
|
|
|
pamVariables = lib.concatStringsSep "\n" (
|
|
lib.mapAttrsToList pamVariable (
|
|
lib.zipAttrsWith (n: lib.concatLists) [
|
|
# Make sure security wrappers are prioritized without polluting
|
|
# shell environments with an extra entry. Sessions which depend on
|
|
# pam for its environment will otherwise have eg. broken sudo. In
|
|
# particular Gnome Shell sometimes fails to source a proper
|
|
# environment from a shell.
|
|
{ PATH = [ config.security.wrapperDir ]; }
|
|
|
|
(lib.mapAttrs (n: lib.toList) cfg.sessionVariables)
|
|
suffixedVariables
|
|
]
|
|
)
|
|
);
|
|
in
|
|
''
|
|
${pamVariables}
|
|
'';
|
|
};
|
|
|
|
}
|