374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
68 lines
2.0 KiB
Nix
68 lines
2.0 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
squashfsTools,
|
|
closureInfo,
|
|
|
|
fileName ? "squashfs",
|
|
# The root directory of the squashfs filesystem is filled with the
|
|
# closures of the Nix store paths listed here.
|
|
storeContents ? [ ],
|
|
# Pseudo files to be added to squashfs image
|
|
pseudoFiles ? [ ],
|
|
noStrip ? false,
|
|
# Compression parameters.
|
|
# For zstd compression you can use "zstd -Xcompression-level 6".
|
|
comp ? "xz -Xdict-size 100%",
|
|
# create hydra build product. will put image in directory instead
|
|
# of directly in the store
|
|
hydraBuildProduct ? false,
|
|
}:
|
|
|
|
let
|
|
pseudoFilesArgs = lib.concatMapStrings (f: ''-p "${f}" '') pseudoFiles;
|
|
compFlag = if comp == null then "-no-compression" else "-comp ${comp}";
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "${fileName}${lib.optionalString (!hydraBuildProduct) ".img"}";
|
|
__structuredAttrs = true;
|
|
|
|
nativeBuildInputs = [ squashfsTools ];
|
|
|
|
buildCommand =
|
|
''
|
|
closureInfo=${closureInfo { rootPaths = storeContents; }}
|
|
|
|
# Also include a manifest of the closures in a format suitable
|
|
# for nix-store --load-db.
|
|
cp $closureInfo/registration nix-path-registration
|
|
|
|
imgPath="$out"
|
|
''
|
|
+ lib.optionalString hydraBuildProduct ''
|
|
|
|
mkdir $out
|
|
imgPath="$out/${fileName}.squashfs"
|
|
''
|
|
+ lib.optionalString stdenv.buildPlatform.is32bit ''
|
|
|
|
# 64 cores on i686 does not work
|
|
# fails with FATAL ERROR: mangle2:: xz compress failed with error code 5
|
|
if ((NIX_BUILD_CORES > 48)); then
|
|
NIX_BUILD_CORES=48
|
|
fi
|
|
''
|
|
+ ''
|
|
|
|
# Generate the squashfs image.
|
|
mksquashfs nix-path-registration $(cat $closureInfo/store-paths) $imgPath ${pseudoFilesArgs} \
|
|
-no-hardlinks ${lib.optionalString noStrip "-no-strip"} -keep-as-directory -all-root -b 1048576 ${compFlag} \
|
|
-processors $NIX_BUILD_CORES -root-mode 0755
|
|
''
|
|
+ lib.optionalString hydraBuildProduct ''
|
|
|
|
mkdir -p $out/nix-support
|
|
echo "file squashfs-image $out/${fileName}.squashfs" >> $out/nix-support/hydra-build-products
|
|
'';
|
|
}
|