374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
119 lines
3.7 KiB
Nix
119 lines
3.7 KiB
Nix
/*
|
||
Impure default args for `pkgs/top-level/default.nix`. See that file
|
||
for the meaning of each argument.
|
||
*/
|
||
|
||
let
|
||
|
||
homeDir = builtins.getEnv "HOME";
|
||
|
||
# Return ‘x’ if it evaluates, or ‘def’ if it throws an exception.
|
||
try =
|
||
x: def:
|
||
let
|
||
res = builtins.tryEval x;
|
||
in
|
||
if res.success then res.value else def;
|
||
|
||
in
|
||
|
||
{
|
||
# We put legacy `system` into `localSystem`, if `localSystem` was not passed.
|
||
# If neither is passed, assume we are building packages on the current
|
||
# (build, in GNU Autotools parlance) platform.
|
||
localSystem ? {
|
||
system = args.system or builtins.currentSystem;
|
||
},
|
||
|
||
# These are needed only because nix's `--arg` command-line logic doesn't work
|
||
# with unnamed parameters allowed by ...
|
||
system ? localSystem.system,
|
||
crossSystem ? localSystem,
|
||
|
||
# Fallback: The contents of the configuration file found at $NIXPKGS_CONFIG or
|
||
# $HOME/.config/nixpkgs/config.nix.
|
||
config ?
|
||
let
|
||
configFile = builtins.getEnv "NIXPKGS_CONFIG";
|
||
configFile2 = homeDir + "/.config/nixpkgs/config.nix";
|
||
configFile3 = homeDir + "/.nixpkgs/config.nix"; # obsolete
|
||
in
|
||
if configFile != "" && builtins.pathExists configFile then
|
||
import configFile
|
||
else if homeDir != "" && builtins.pathExists configFile2 then
|
||
import configFile2
|
||
else if homeDir != "" && builtins.pathExists configFile3 then
|
||
import configFile3
|
||
else
|
||
{ },
|
||
|
||
# Overlays are used to extend Nixpkgs collection with additional
|
||
# collections of packages. These collection of packages are part of the
|
||
# fix-point made by Nixpkgs.
|
||
overlays ?
|
||
let
|
||
isDir = path: builtins.pathExists (path + "/.");
|
||
pathOverlays = try (toString <nixpkgs-overlays>) "";
|
||
homeOverlaysFile = homeDir + "/.config/nixpkgs/overlays.nix";
|
||
homeOverlaysDir = homeDir + "/.config/nixpkgs/overlays";
|
||
overlays =
|
||
path:
|
||
# check if the path is a directory or a file
|
||
if isDir path then
|
||
# it's a directory, so the set of overlays from the directory, ordered lexicographically
|
||
let
|
||
content = builtins.readDir path;
|
||
in
|
||
map (n: import (path + ("/" + n))) (
|
||
builtins.filter (
|
||
n:
|
||
(
|
||
builtins.match ".*\\.nix" n != null
|
||
&&
|
||
# ignore Emacs lock files (.#foo.nix)
|
||
builtins.match "\\.#.*" n == null
|
||
)
|
||
|| builtins.pathExists (path + ("/" + n + "/default.nix"))
|
||
) (builtins.attrNames content)
|
||
)
|
||
else
|
||
# it's a file, so the result is the contents of the file itself
|
||
import path;
|
||
in
|
||
if pathOverlays != "" && builtins.pathExists pathOverlays then
|
||
overlays pathOverlays
|
||
else if builtins.pathExists homeOverlaysFile && builtins.pathExists homeOverlaysDir then
|
||
throw ''
|
||
Nixpkgs overlays can be specified with ${homeOverlaysFile} or ${homeOverlaysDir}, but not both.
|
||
Please remove one of them and try again.
|
||
''
|
||
else if builtins.pathExists homeOverlaysFile then
|
||
if isDir homeOverlaysFile then
|
||
throw (homeOverlaysFile + " should be a file")
|
||
else
|
||
overlays homeOverlaysFile
|
||
else if builtins.pathExists homeOverlaysDir then
|
||
if !(isDir homeOverlaysDir) then
|
||
throw (homeOverlaysDir + " should be a directory")
|
||
else
|
||
overlays homeOverlaysDir
|
||
else
|
||
[ ],
|
||
|
||
crossOverlays ? [ ],
|
||
|
||
...
|
||
}@args:
|
||
|
||
# If `localSystem` was explicitly passed, legacy `system` should
|
||
# not be passed, and vice-versa.
|
||
assert args ? localSystem -> !(args ? system);
|
||
assert args ? system -> !(args ? localSystem);
|
||
|
||
import ./. (
|
||
builtins.removeAttrs args [ "system" ]
|
||
// {
|
||
inherit config overlays localSystem;
|
||
}
|
||
)
|